Use Non-Frames Version Previous Page Next Page
Instrument Control: Reinitialization

reinit, rigoto, rireturn

           reinit     label
           rigoto     label
           rireturn

Description

These statements permit an instrument to reinitialize itself during performance.

reinit – whenever this statement is encountered during a p-time pass, performance is temporarily suspended while a special Initialization pass, beginning at label and continuing to rireturn or endin, is executed. Performance will then be resumed from where it left off.

rigoto – similar to igoto, but effective only during a reinit pass (i.e., no-op at standard i-time). This statement is useful for bypassing units that are not to be reinitialized.

rireturn – terminates a reinit pass (i.e., no-op at standard i-time). This statement, or an endin, will cause normal performance to be resumed.

Example

The following statements will generate an exponential control signal whose value moves from 440 to 880 exactly ten times over the duration p3.

  
; reinit example by Brian Willkie (12 March 2002)

; start reinit_example.orc ------------------

  sr       = 44100
  kr       = 44100
  ksmps    = 1
  nchnls   = 1

           instr 1

reset:
           timout    0, p3/10, contin
           reinit    reset

contin:
  kLine    expon     440, p3/10, 880
  aSig     oscil     10000, kLine, 1
           out       aSig
           rireturn 

           endin
					 
; end reinit_example.orc --------------------

; start reinit_example.sco ------------------
  f1 0 4096 10 1

  i1 0 10
  e
; end reinit_example.sco --------------------

Use Non-Frames Version Previous Page Next Page
Instrument Control: Reinitialization