Use Non-Frames Version Previous Page Next Page
Signal Generators: Models and Emulations

cabasa, crunch, sekere, sandpaper, stix

  ar      cabasa     iamp, idettack[, knum, kdamp, kmaxshake]
  ar      crunch     iamp, idettack[, knum, kdamp, kmaxshake]
  ar      sekere     iamp, idettack[, knum, kdamp, kmaxshake]
  ar      sandpaper  iamp, idettack[, knum, kdamp, kmaxshake]
  ar      stix       iamp, idettack[, knum, kdamp, kmaxshake]

Description

Semi-physical models of various percussion sounds.

Initialization

iamp – Amplitude of output. Note: As these instruments are stochastic, this is only a approximation.

idettack – period of time over which all sound is stopped

Performance

knum – The number of beads, teeth, bells, timbrels, etc. If, zero the default value is:

     
         cabasa       = 512.0000
         crunch       =   7.0000
         sekere       =  64.0000
         sandpaper    = 128.0000
         stix         =  30.0000
	

kdamp – the damping factor of the instrument. The value is used as an adjustment around the defaults, with 1 being no damping. If zero, the default values are used. The defaults are:

         cabasa       =   0.9970
         crunch       =   0.99806
         sekere       =   0.9990
         sandpaper    =   0.9990
         stix         =   0.9980
	

kmaxshake – amount of energy to add back into the system. The value should be in range 0 to 1.

Example

;orchestra ---------------

  sr      =           44100
  kr      =            4410
  ksmps   =              10
  nchnls  =               1

  gknum      init       0           ;initialize optional arguments
  gkdamp     init       0           ;   for use with all instruments
  gkmaxshake init       0                

          instr 01                  ;an example of a cabasa
  a1      cabasa      p4, 0.01, gknum, gkdamp, gkmaxshake
          out         a1
          endin

          instr 02                  ;an example of a crunch
  a1      crunch      p4, 0.01, gknum, gkdamp, gkmaxshake
          out         a1
          endin

          instr 03                  ;an example of a sekere
  a1      sekere      p4, 0.01, gknum, gkdamp, gkmaxshake
          out         a1
          endin

          instr 04                  ;an example of sandpaper blocks
  a1      line        2, p3, 2                             ;preset amplitude increase
  a2      sandpaper   p4, 0.01, gknum, gkdamp, gkmaxshake  ;sandpaper needs a little amp help at these settings
  a3      product     a1, a2                               ;increase amplitude
          out         a3
          endin

          instr 05                  ;an example of stix
  a1      line        20, p3, 20                           ;preset amplitude increase
  a2      stix        p4, 0.01, gknum, gkdamp, gkmaxshake  ;stix needs a little amp help at these settings
  a3      product     a1, a2                               ;increase amplitude
          out         a3
          endin

;score -------------------

   i1 0 1 26000
   i2 2 1 26000
   i3 4 1 26000
   i4 6 1 26000
   i5 8 1 26000
   e

Author

John ffitch
University of Bath, Codemist Ltd.
Bath, UK
New in Csound version 4.07


Use Non-Frames Version Previous Page Next Page
Signal Generators: Models and Emulations