Use Non-Frames Version Previous Page Next Page
Signal Generators Models and Emulations

guiro, tambourine, bamboo, dripwater, sleighbells


  ar      guiro       iamp, idettack[, knum, kdamp, kmaxshake, kfreq, kfreq1]

  ar      tambourine  iamp, idettack[, knum, kdamp, kmaxshake, kfreq, kfreq1, kfreq2]

  ar      bamboo      iamp, idettack[, knum, kdamp, kmaxshake, kfreq, kfreq1, kfreq2]

  ar      dripwater   iamp, idettack[, knum, kdamp, kmaxshake, kfreq, kfreq1, kfreq2]

  ar      sleighbells iamp, idettack[, knum, kdamp, kmaxshake, kfreq, kfreq1, kfreq2]


Description

Semi-physical models of various percussion sounds.

Initialization

iamp – Amplitude of output. Note As these instruments are stochastic, this is only a approximation.

idettack – period of time over which all sound is stopped

Performance

knum – The number of beads, teeth, bells, timbrels, etc. If, zero the default value is:

     

         guiro        = 128.0000

         tambourine   =  32.0000

         bamboo       =   1.2500

         dripwater    =  10.0000

         sleighbells  =  32.0000

	

kdamp – the damping factor of the instrument. The value is used as an adjustment around the defaults, with 1 being no damping. If zero, the default values are used. The defaults are:


         guiro        =   1.0000

         tambourine   =   0.9985

         bamboo       =   0.9999

         dripwater    =   0.9950

         sleighbells  =   0.9994

	

kmaxshake – amount of energy to add back into the system. The value should be in range 0 to 1.

kfreq – the main resonant frequency. The default values are:


         guiro       = 2500.0000

         tambourine  = 2300.0000

         bamboo      = 2800.0000

         dripwater   =  450.0000

         sleighbells = 2500.0000

	

kfreq1 – the first resonant frequency. The default values are:


         tambourine  = 5600.0000

         bamboo      = 2240.0000

         dripwater   =  600.0000

         sleighbells = 5300.0000

	

kfreq2 – the second resonant frequency. The default values are:


         tambourine  = 8100.0000

         bamboo      = 3360.0000

         dripwater   =  750.0000

         sleighbells = 6500.0000

	

Example




;orchestra ---------------



  sr      =           44100

  kr      =            4410

  ksmps   =              10

  nchnls  =               1



          instr 01                     ;example of a guiro

  a1      guiro       p4, 0.01

          out         a1

          endin



          instr 02                     ;example of a tambourine

  a1      tambourine  p4, 0.01

          out         a1

          endin



          instr 03                     ;example of bamboo

  a1      bamboo      p4, 0.01

          out         a1

          endin



          instr 04                     ;example of a water drip

  a1      line        5, p3, 5         ;preset an amplitude boost

  a2      dripwater   p4, 0.01, 0, .9  ;dripwater needs a little amplitude help at these values

  a3      product     a1, a2           ;increase amplitude

          out         a3

          endin



          instr 05                     ;an example of sleighbells

  a1      sleighbells p4, 0.01

          out         a1

          endin



;score -------------------



   i1 0 1 20000

   i2 2 1 20000

   i3 4 1 20000

   i4 6 1 20000

   i5 8 1 20000

   e



Author

John ffitch
University of Bath, Codemist Ltd.
Bath, UK
New in Csound version 4.07


Use Non-Frames Version Previous Page Next Page
Signal Generators Models and Emulations